home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-users-of-norman / CUON_18_(11-1984).d64 / lost dutchman (.txt) < prev    next >
Commodore BASIC  |  2019-04-13  |  3KB  |  87 lines
  1. 100 REM  LOST DUTCHMAN MINE
  2. 110 GOSUB 710
  3. 120 SR=0:GL=2020
  4. 130 PRINT "SCORE:"SR
  5. 140 JY=PEEK(56321):JY=15-(JY AND 15):K=PEEK(197):J=PEEK(653):AL=L
  6. 150 POKEL,32:IFJY=1ORJY=5ORJY=9OR(K=7 AND J=1) THEN AL=AL-40
  7. 160 IFJY=2ORJY=6ORJY=10OR(K=7 AND J=0)THEN AL=AL+40
  8. 170 IF(JY>3 AND JY<7)OR(K=2 AND J=1)THEN AL=AL-1
  9. 180 IFJY>7OR(K=2 AND J=0) THENAL=AL+1
  10. 190 IFPEEK(AL)<>160THENL=AL
  11. 200 IFPEEK(L)=GTHEN380
  12. 210 IFPEEK(L)=46THENSR=SR+1
  13. 220 IFPEEK(L)=CLTHENSR=SR+100:PRINT"FIND ROOM":FORT=1TO999:NEXT
  14. 230 IFPEEK(L)=CLTHENPRINT"          "
  15. 240 IFL=RLTHEN520
  16. 250 IFL=GLTHEN630
  17. 260 POKEL,I:LY=INT((L-S)/40):LX=L-S-LY*40
  18. 270 NG=3:IFRL=2020THENNG=1
  19. 280 FORX=1TONG:M=G(X):POKEM,32
  20. 290 GY=INT((M-S)/40):GX=M-S-GY*40
  21. 300 IFGX<LX AND (PEEK(M+1)<50ORPEEK(M+1)=I)THENM=M+1
  22. 310 IFGX>LX AND (PEEK(M-1)<50 OR PEEK(M-1)=I)THENM=M-1
  23. 320 IFGY>LY AND (PEEK(M-40)<50 OR PEEK(M-40)=I)THENM=M-40
  24. 330 IFGY<LY AND (PEEK(M+40)<50 OR PEEK(M+40)=I)THENM=M+40
  25. 340 G(X)=M:POKEM,G:IFG=65 THENG=88:GOTO360
  26. 350 IFG=88THENG=65
  27. 360 IFM=LTHEN380
  28. 370 NEXTX:GOTO130
  29. 380 SO=54272:FORX=0TO24:POKESO+X,0:NEXTX
  30. 390 POKESO+14,5:POKESO+18,16:POKESO+3,1:POKESO+24,143
  31. 400 POKESO+6,240:POKESO+4,65
  32. 410 POKE53280,2:F1=5389:FORX=0TO119:F=F1+PEEK(SO+27)*3.5
  33. 420 H=INT(F/256):L=F-H*256
  34. 430 IFINT(X/10)/2<>INT(INT(X/10)/2)THENPOKE53280,2:POKE53281,2
  35. 440 IFINT(X/10)/2<>INT(INT(X/10)/2)THENPOKE53280,14:POKE53281,1
  36. 450 POKESO,L:POKESO+1,H:NEXTX
  37. 460 POKESO+24,0
  38. 470 FORX=1TO2000:NEXTX
  39. 480 PRINT"[147]":PRINT:PRINT
  40. 490 PRINT"YOU LOSE!":PRINT"MY GHOST GOT YOU!"
  41. 500 PRINT:PRINT"HA HA HA HA HA!"
  42. 510 GOTO680
  43. 520 PRINT"[147]":PRINT"[144]                   "
  44. 530 FORX=1TO12:PRINT"  ";TAB( 18);" ": NEXTX
  45. 540 PRINT"[144]                   "
  46. 550 S=1106:B=160:BX=49
  47. 560 FORX=0TOBX:POKES+40* INT(RND(8)*12)+INT(RND(8)*17),B:NEXTX
  48. 570 FORX=55296TO56295:POKEX,0:NEXTX
  49. 580 GL=S+40*INT(RND(8)*12)+INT(RND(8)*17):POKEGL,164
  50. 590 G=88:FORX=1TO3:G(X)=1513:NEXTX:L=S+8
  51. 600 FORX=1TO3:POKEG(X),G:NEXTX:POKEL,I
  52. 610 RL=2020
  53. 620 FORT=1TO2500:NEXTT:GOTO130
  54. 630 FORX=1TO2000:NEXTX
  55. 640 PRINT"[147]":PRINT:PRINT
  56. 650 PRINTTAB( 11)"YOU FOUND THE GOLD!":PRINT:PRINT
  57. 660 PRINTTAB( 11)"FINAL SCORE:"SR*10
  58. 670 PRINT:PRINT
  59. 680 POKE198,0:PRINTTAB( 14)"PLAY AGAIN";: INPUTQ$
  60. 690 IFLEFT$(Q$,1)="Y"THEN110
  61. 700 END
  62. 710 PRINT"[147][144]":POKE53281,1
  63. 720 PRINT"     LOST DUTCHMAN MINE ADVENTURE":PRINT
  64. 730 PRINT"SOME TIME AGO, IN ARIZONA'S SUPERSTITION";
  65. 740 PRINT"MOUNTAINS, THE GOLD OF THE LOST"
  66. 750 PRINT"DUTCHMAN WAS LOST IN A CAVE.":PRINT
  67. 760 PRINT"AS YOU SEARCH THE CAVES BE SURE TO"
  68. 770 PRINT"AVOID THE GHOSTS ([216]).":PRINT
  69. 780 PRINT"COLLECT DOTS FOR POINTS AND THE"
  70. 790 PRINT"MYSTERIOUS CLUES (?[146]) TO HELP YOU ON     THE WAY":PRINT
  71. 800 PRINT"USE A JOYSTICK OR THE CURSOR KEYS TO    MOVE."
  72. 810 PRINT: PRINT"ENTER YOUR FIRST INITIAL."
  73. 820 GETI$:IFI$=""THEN820
  74. 830 IFASC(I$)<65 OR ASC(I$)>90 THEN820
  75. 840 PRINT"[147]": PRINT "[144]                                      "
  76. 850 FORX=1TO19:PRINT"  "; TAB( 37);" ": NEXTX
  77. 860 PRINT"                                      "
  78. 870 S=1106:B=160:G=146:CL=191:I= ASC (I$)-64
  79. 880 BX=249:C=99
  80. 890 FORX=55296TO56295:POKEX,0:NEXTX
  81. 900 FORX=0TOBX:POKES+40* INT (RND(8)*19)+ INT (RND(8)*35),B:NEXTX
  82. 910 FORX=0TOC:POKES+40* INT ( RND(8)*19)+INT (RND(8)*35),46:NEXTX
  83. 920 FORX=0TO3:RL=S+40* INT(RND(8)*19)+ INT(RND(8)*35):POKERL,CL:NEXTX
  84. 930 G=88:G(1)=1428:G(2)=1458:G(3)=1764:L=S+18
  85. 940 FORX=1TO3:POKEG(X),G:NEXTX:POKEL,I
  86. 950 RETURN
  87.